:: FILE_ID.DIZ file collector batch (c)1996 Terry Newton
:: Scans the specified drive/dir and writes the contents
:: of any FILE_ID.DIZ files to the specified output file
@echo off
if .%1==.Loop goto %2
echo.
echo FILE_ID.DIZ File Collector
echo --------------------------
if .%1==. echo Drive or directory not specified
if .%1==. echo Syntax: %0 drive outfile  or  %0 dir outfile
if .%1==. echo Collects FILE_ID.DIZ files to specified file
if .%1==. echo Note - current directory must be writable
if .%1==. echo Examples: %0 f: fdiz.txt 
if .%1==. echo           %0 c:\games c:\games\games.txt 
if .%1==. goto endofbatch
if .%2==. echo Output filename not specified
if .%2==. goto endofbatch
echo FILE_ID.DIZ descriptions for %1...>%2
if exist %2 goto init2
echo Output filename not valid
goto endofbatch
:init2
echo --------------------------------------------------->%2
echo.>>%2
for %%a in (enter.com new.bat new.exe new.com) do if exist %%a goto Conflict
:: !!! modify this part if LOADFIX.COM not in listed directories !!!
if exist c:\dos\loadfix.com copy c:\dos\loadfix.com enter.com>nul 
if exist c:\msdos\loadfix.com copy c:\msdos\loadfix.com enter.com>nul 
if exist c:\windows\command\loadfix.com copy c:\windows\command\loadfix.com enter.com>nul 
if not exist enter.com goto Missing
%comspec% /e:2000 /c %0 Loop Shell %1 %2
for %%a in (dir$.$$ dir$-$.bat new.bat enter.com) do if exist %%a del %%a
goto endofbatch
:Conflict
echo NEW or ENTER.COM exists, delete or rename
goto endofbatch
:Missing
echo Can't find LOADFIX.COM, edit this batch
goto endofbatch
:Shell
set outfile=%4
echo Checking base directory...
if exist %3\file_id.diz call %0 Loop AddFile %3
dir %3\*.* /s /ad /b >dir$.$$
echo.>>dir$.$$
echo @echo off>dir$-$.bat
type dir$.$$|date|find "Enter">>dir$-$.bat
echo @echo off>new.bat
echo %0 Loop DoDir %%3>>new.bat
%comspec% /c dir$-$.bat
goto endofbatch
:DoDir
if .%3==. goto endofbatch
echo Checking in %3...
if exist %3\file_id.diz call %0 Loop AddFile %3
goto endofbatch
:AddFile
echo %3...>>%outfile%
echo.>>%outfile%
type %3\file_id.diz>>%outfile%
echo.>>%outfile%
echo --------------------------------------------------->>%outfile%
echo.>>%outfile%
:endofbatch