:: copy redmaker to ram drive and run
:: compress warcode when on hard drive
:: calls redmaker pkzip pkunzip
:: to set up a ram drive, add to config.sys...
:: DEVICEHIGH=C:\WINDOWS\RAMDRIVE.SYS 384 512 512 /E
@echo off
:: modify below to system...
:: installed drive letter
set hd=D
:: ram disk letter
set rd=F
:: --------------------
if exist %hd%:redmaker.* if exist %rd%:\nul goto ok
echo Program or drive not found, edit batch
goto end
:ok
echo Copying files to ram disk...
if exist %rd%:\redmaker.* del %rd%:\redmaker.*
if exist %rd%:\*.war del %rd%:\*.war
if exist %rd%:\*.red del %rd%:\*.red
copy redmaker.* %rd%:\ >nul
if exist *.war copy *.war %rd%:\ >nul
if exist *.red copy *.red %rd%:\ >nul 
if not exist %rd%:\warcode\*.* goto nodel
echo y|del %rd%:\warcode\*.* >nul
rd %rd%:\warcode
:nodel
if not exist warcode.zip goto run
md %rd%:\warcode
pkunzip warcode.zip %rd%:\warcode >nul
:run
%rd%:
cd\
qbasic /run redmaker
%hd%:
if exist %rd%:\warcode\*.red goto save
echo Nothing to save
goto end
:save
echo Saving files...
if exist %rd%:\*.def copy %rd%:\*.def >nul
if exist %rd%:\*.war copy %rd%:\*.war >nul
if exist warcode.zip del warcode.zip
pkzip warcode.zip %rd%:\warcode\*.* > nul
cls
:end